#include "Macros.fxh" //from FNA
#include "Lighting.fxh"

static const int NUM_SHADOW_CASCADES = 4;

DECLARE_TEXTURE(gPosition, 0);
DECLARE_TEXTURE(gAlbedo, 1);
DECLARE_TEXTURE(gNormal, 2);
DECLARE_TEXTURE(gMetallicRoughness, 3);
DECLARE_TEXTURE(shadowMapOne, 4);
DECLARE_TEXTURE(shadowMapTwo, 5);
DECLARE_TEXTURE(shadowMapThree, 6);
DECLARE_TEXTURE(shadowMapFour, 7);

BEGIN_CONSTANTS

    float3 EyePosition                                         _ps(c0)    _cb(c0);

    float3 DirectionalLightDirection                           _ps(c1)    _cb(c1);
    float3 DirectionalLightColor                               _ps(c2)    _cb(c2);

    float CascadeFarPlanes[NUM_SHADOW_CASCADES]                _ps(c3)    _cb(c3);

    float ShadowMapSize                                        _ps(c7)    _cb(c7);

MATRIX_CONSTANTS

    float4x4 LightSpaceMatrixOne                               _ps(c8)    _cb(c8);
    float4x4 LightSpaceMatrixTwo                               _ps(c12)   _cb(c12);
    float4x4 LightSpaceMatrixThree                             _ps(c16)   _cb(c16);
    float4x4 LightSpaceMatrixFour                              _ps(c20)   _cb(c20);

    // used to select shadow cascade
    float4x4 ViewMatrix                                        _ps(c24)   _cb(c24);

END_CONSTANTS

static float2 poissonDisk[16] = 
{
   float2( -0.94201624, -0.39906216 ), 
   float2( 0.94558609, -0.76890725 ), 
   float2( -0.094184101, -0.92938870 ), 
   float2( 0.34495938, 0.29387760 ), 
   float2( -0.91588581, 0.45771432 ), 
   float2( -0.81544232, -0.87912464 ), 
   float2( -0.38277543, 0.27676845 ), 
   float2( 0.97484398, 0.75648379 ), 
   float2( 0.44323325, -0.97511554 ), 
   float2( 0.53742981, -0.47373420 ), 
   float2( -0.26496911, -0.41893023 ), 
   float2( 0.79197514, 0.19090188 ), 
   float2( -0.24188840, 0.99706507 ), 
   float2( -0.81409955, 0.91437590 ), 
   float2( 0.19984126, 0.78641367 ), 
   float2( 0.14383161, -0.14100790 ) 
};

struct VertexInput
{
    float4 Position : POSITION;
    float2 TexCoord : TEXCOORD;
};

struct PixelInput
{
    float4 Position : SV_POSITION;
    float2 TexCoord : TEXCOORD0;
};

PixelInput main_vs(VertexInput input)
{
    PixelInput output;

    output.Position = input.Position;
    output.TexCoord = input.TexCoord;

    return output;
}

// Pixel Shader

// Returns a random number based on a vec3 and an int.
float random(float3 seed, int i){
	float4 seed4 = float4(seed, i);
	float dot_product = dot(seed4, float4(12.9898,78.233,45.164,94.673));
	return frac(sin(dot_product) * 43758.5453);
}

float PoissonCoord(sampler shadowMap, float3 worldPosition, float2 texCoord, float fragmentDepth, float bias)
{
    float visibility = 1.0;

    for (int i = 0; i < 16; i++)
    {
        int index = int(16.0 * random(floor(worldPosition * 1000.0), i)) % 16;

        if (tex2D(shadowMap, texCoord + poissonDisk[i] / 700.0).r < fragmentDepth - bias)
        {
            visibility -= 0.2;
        }
    }

    return visibility;
}

float ComputeShadow(float3 positionWorldSpace, float3 N, float3 L)
{
    float bias = 0.005 * tan(acos(dot(N, L)));
    bias = clamp(bias, 0, 0.01);

    float4 positionCameraSpace = mul(float4(positionWorldSpace, 1.0), ViewMatrix);

    int shadowCascadeIndex = 0; // 0 is closest
    for (int i = 0; i < NUM_SHADOW_CASCADES; i++)
    {
        if (abs(positionCameraSpace.z) < CascadeFarPlanes[i])
        {
            shadowCascadeIndex = i;
            break;
        }
    }

    float4x4 lightSpaceMatrix;

    if (shadowCascadeIndex == 0)
    {
        lightSpaceMatrix = LightSpaceMatrixOne;
    }
    else if (shadowCascadeIndex == 1)
    {
        lightSpaceMatrix = LightSpaceMatrixTwo;
    }
    else if (shadowCascadeIndex == 2)
    {
        lightSpaceMatrix = LightSpaceMatrixThree;
    }
    else
    {
        lightSpaceMatrix = LightSpaceMatrixFour;
    }

    float4 positionLightSpace = mul(float4(positionWorldSpace, 1.0), lightSpaceMatrix);
   
    // maps to [-1, 1]
    float3 projectionCoords = positionLightSpace.xyz / positionLightSpace.w;

    // maps to [0, 1]
    projectionCoords.x = (projectionCoords.x * 0.5) + 0.5;
    projectionCoords.y = (projectionCoords.y * 0.5) + 0.5;
    projectionCoords.y *= -1;
    // in XNA clip z is 0 to 1 already

    if (projectionCoords.z > 1.0)
    {
        return 1.0;
    }

    float inc = 1.0 / ShadowMapSize; // TODO: shadow map size uniform

    // PCF + Poisson soft shadows
    float visibility = 0.0;
    // for (int row = -1; row <= 1; row++)
    // {
    //     for (int col = -1; col <= 1; col++)
    //     {
    //         if (shadowCascadeIndex == 0)
    //         {
    //             visibility += PoissonCoord(SAMPLER(shadowMapOne), positionWorldSpace, projectionCoords.xy + float2(row, col) * inc, projectionCoords.z, bias);
    //         }
    //         else if (shadowCascadeIndex == 1)
    //         {
    //             visibility += PoissonCoord(SAMPLER(shadowMapTwo), positionWorldSpace, projectionCoords.xy + float2(row, col) * inc, projectionCoords.z, bias);
    //         }
    //         else if (shadowCascadeIndex == 2)
    //         {
    //             visibility += PoissonCoord(SAMPLER(shadowMapThree), positionWorldSpace, projectionCoords.xy + float2(row, col) * inc, projectionCoords.z, bias);
    //         }
    //         else
    //         {
    //             visibility += PoissonCoord(SAMPLER(shadowMapFour), positionWorldSpace, projectionCoords.xy + float2(row, col) * inc, projectionCoords.z, bias);
    //         }
    //     }
    // }

    // visibility /= 9.0;

    if (shadowCascadeIndex == 0)
    {
        visibility = PoissonCoord(SAMPLER(shadowMapOne), positionWorldSpace, projectionCoords.xy, projectionCoords.z, bias);
    }
    else if (shadowCascadeIndex == 1)
    {
        visibility = PoissonCoord(SAMPLER(shadowMapTwo), positionWorldSpace, projectionCoords.xy, projectionCoords.z, bias);
    }
    else if (shadowCascadeIndex == 2)
    {
        visibility = PoissonCoord(SAMPLER(shadowMapThree), positionWorldSpace, projectionCoords.xy, projectionCoords.z, bias);
    }
    else
    {
        visibility = PoissonCoord(SAMPLER(shadowMapFour), positionWorldSpace, projectionCoords.xy, projectionCoords.z, bias);
    }

    return visibility;
}

float4 ComputeColor(
    float3 worldPosition,
    float3 worldNormal,
    float3 albedo,
    float metallic,
    float roughness
) {
    float3 V = normalize(EyePosition - worldPosition);
    float3 N = normalize(worldNormal);

    float3 F0 = float3(0.04, 0.04, 0.04);
    F0 = lerp(F0, albedo, metallic);

    float3 L = normalize(DirectionalLightDirection);
    float3 radiance = DirectionalLightColor;

    float shadow = ComputeShadow(worldPosition, N, L);
    float3 color = ComputeLight(L, radiance, F0, V, N, albedo, metallic, roughness, shadow);

    return float4(color, 1.0);
}

float4 main_ps(PixelInput input) : SV_TARGET0
{
    float3 worldPosition = SAMPLE_TEXTURE(gPosition, input.TexCoord).rgb;
    float3 normal = SAMPLE_TEXTURE(gNormal, input.TexCoord).xyz;
    float3 albedo = SAMPLE_TEXTURE(gAlbedo, input.TexCoord).rgb;
    float2 metallicRoughness = SAMPLE_TEXTURE(gMetallicRoughness, input.TexCoord).rg;

    return ComputeColor(
        worldPosition,
        normal,
        albedo,
        metallicRoughness.r,
        metallicRoughness.g
    );
}

Technique DeferredPBR_Directional
{
    Pass
    {
        VertexShader = compile vs_3_0 main_vs();
        PixelShader = compile ps_3_0 main_ps();
    }
}